@echo off
if "%lang%"=="" set lang=EN
cls
for %%x in ( 0 1 2 3 4 11 12 13 14 15 ) do LOCALIZE 0.%%x
%fdosroot%\bin\choice /N /C:123vVrRqQ %menu1txt%
if errorlevel 1 set menu1_nr=INSTFDOS
if errorlevel 2 set menu1_nr=QUIT
if errorlevel 3 set menu1_nr=BOOTDISK
if errorlevel 4 set menu1_nr=VIEW
if errorlevel 5 set menu1_nr=VIEW
if errorlevel 6 set menu1_nr=REBOOT
if errorlevel 7 set menu1_nr=REBOOT
if errorlevel 8 set menu1_nr=QUIT
if errorlevel 9 set menu1_nr=QUIT
goto end
:end



@echo off
if "%lang%"=="" set lang=EN
set menu2_nr=INSTFDOS
cls
if not exist c:\nul goto end
for %%x in ( 0 1 2 3 4 5 6 7 8 9 9 ) do A:\FREEDOS\localize 1.%%x
REM set TEXTMENU=
%fdosroot%\bin\choice /N /C:12345qQ %menu2txt%
if errorlevel 1 set menu2_nr=INSTFDOS
if errorlevel 2 set menu2_nr=SETKEYB
if errorlevel 3 set menu2_nr=SETSIZE
if errorlevel 4 set menu2_nr=SETSCRN
if errorlevel 5 set menu2_nr=SETLANG
if errorlevel 6 set menu2_nr=QUIT
if errorlevel 7 set menu2_nr=QUIT
goto end

:end
rem Fdisk and then Quit must lead to menu 1
if "%TEXTMENU%"=="QUIT" set menu2_nr=QUIT
set TEXTMENU=

@echo off
%fdosroot%\bin\locate.com postinst.bat /O:&D /N /F:1 /G
REM %fdosroot%\bin\locate.com postinst.bat /S:5284! /O:&D /N /F:1 /G

if exist postinst.bat postinst.bat
goto error

:error
echo.
echo current directory: %_CWD%
echo Error: installation has been cancelled somehow.
echo.
echo Configuration files have not been created.
echo Please execute the following:
echo.
echo SYS A: C:
echo.
pause {end-of-message}
goto end
:end











@echo off
set fdosroot=%cdrom%freedos\setup
set path=A:\freedos;%fdosroot%\bin;%fdosroot%\install
cls
for %%x in ( [%lang%] [%color%] [%key%] [%instmode%] [%display%] ) do if %%x==[] goto defaults
goto optmenu1

:optmenu1
set menu1_nr=
call %fdosroot%\batch\menu1.bat
echo.
if "%menu1_nr%"=="INSTFDOS" goto optmenu2
if "%menu1_nr%"=="BOOTDISK" call %fdosroot%\batch\bootdisk.bat
if "%menu1_nr%"=="QUIT" LOCALIZE 0.17
if "%menu1_nr%"=="QUIT" goto end
if "%menu1_nr%"=="VIEW" %fdosroot%\bin\pg %cdrom%freedos\docs\install3.txt
if "%menu1_nr%"=="REBOOT" FDISK /REBOOT
cls
goto optmenu1

:defaults
alias menu=%fdosroot%\batch\autorun.bat
set nlspath=%fdosroot%\nls
set lang=EN
set color=Color
for %%x in ( 8086 80186 80286 ) do if "%cputype%"=="%%x" set color=Mono
set display=yes
set instmode=Mini
if not "%disksrc%"=="B:" goto optmenu1
if exist A:\freedos\localize.%lang% goto optmenu1
if exist %fdosroot%\nls\localize.%lang% copy /y %fdosroot%\nls\localize.%lang% A:\freedos\localize.%lang%
if exist A:\freedos\localize.%lang% set nlspath=A:\freedos
cls
goto optmenu1

:optmenu2
set menu2_nr=
call %fdosroot%\batch\menu2.bat
echo.
if "%menu2_nr%"=="INSTFDOS" goto installr
if "%menu2_nr%"=="SETLANG"  goto sel_lang
if "%menu2_nr%"=="SETSCRN"  goto sel_scrn
if "%menu2_nr%"=="SETKEYB"  goto sel_keyb
if "%menu2_nr%"=="SETSIZE"  goto sel_mode
if "%menu2_nr%"=="QUIT"     goto optmenu1
goto optmenu2

:installr
rem ## provide general information
cls
for %%x in ( %fdosroot%\LANGUAGE\%LANG%\BETA*.TXT ) DO if exist %%x TYPE %%x 
echo.
pause 
rem ## provide installation notes.
for %%x in ( %fdosroot%\LANGUAGE\%LANG%\INST.TXT ) DO if exist %%x %cdrom%\freedos\setup\bin\pg %%x 

set TEXTMENU=
call %fdosroot%\batch\textmenu.bat
if "%TEXTMENU%"=="QUIT" goto optmenu2
if "%TEXTMENU%"=="QUIT" goto optmenu2
rem Do not CALL this, but let it be the end-option.
rem But what about the INSTALLER not being run? how to solve that?
if exist %fdosroot%\batch\postinst.bat %fdosroot%\batch\postinst.bat
goto optmenu2

:sel_lang
set LANG=EN
cls
goto optmenu2

:sel_scrn
echo What kind of monitor do you have?
echo 1) Color     
echo 2) Monochrome
echo.
echo  NB: if graphical installer does not work properly, please pick monochrome
%fdosroot%\bin\choice /C:12 "                "
if errorlevel 1 set color=Color
if errorlevel 2 set color=Mono
goto optmenu2

:sel_keyb
cls
type %fdosroot%\language\regional.txt
echo.
echo.
echo Please enter the number corresponding to the name which best described
set /P choice=your current location (confirm input by pressing ENTER):
if "%choice%"=="" goto optmenu2
if not "%display%"=="" LH %fdosroot%\bin\DISPLAY CON=(EGA,,1)
call %fdosroot%\batch\regional.bat %choice%
set display=
goto optmenu2

:sel_mode
echo What kind of install do you want?
echo 1) Full install
echo 2) Minimal install
%fdosroot%\bin\choice /C:12 "         "
if errorlevel 1 set instmode=Full
if errorlevel 2 set instmode=Mini
goto optmenu2

:end



@echo off
cls
rem Check for memdisk existence, errorlevel 1=found ; 0=notfound
set dest=A:
if "%OS%"=="Windows_NT" goto begin
if not exist a:\freedos\ifmemdsk.com goto begin
a:\freedos\ifmemdsk.com 
if errorlevel 3 goto begin
if errorlevel 1 set dest=B:
goto begin

:begin
title FreeDOS Bootdisk Builder
cls
echo Welcome to the bootdisk builder. this will create a bootdisk for you.
echo.
if not "%OS%"=="Windows_NT" goto begin2
echo Please insert a (non)empty formatted diskette in diskdrive and press a key to continue
goto emptydsk
:begin2
if not "%cdrom%"=="" CDD %cdrom%
cls
if "%dest%"=="B:" echo Please insert a (non)empty formatted diskette in your diskette drive.
if "%dest%"=="A:" echo please remove bootdisk and insert a (non)empty formatted diskette in your diskette drive
goto emptydsk

:emptydsk
pause Press a key to continue or Control-C to abort.
rem show files, trying to detect kernels.
attrib -r -h -s %dest%\*.*
cls
rem kernel files and cdromdrivers (as long as atapicdd.sys isn't performing good/stable enough)
for %%x in ( %dest%\io.sys %dest%\msdos.sys %dest%\oakcdrom.sys ) do if exist %%x attrib +r %%x
for %%x in ( %dest%\*.* ) do del %%x
rem all files in root removed, except for kernel files.
goto docopy

:docopy
if "%dest%"=="A:" \freedos\3rdparty\extract -ox \isolinux\data\fdboot.img %dest% *.* 
if "%dest%"=="B:" xcopy /s /y A:\*.* %dest%
rem files are now present on diskette!
rem setup stable cdromdriver, delete recreatable files
if exist %dest%\oakcdrom.sys copy /y %dest%\oakcdrom.sys %dest%\driver\vide-cdd.sys
if exist %dest%\metakern.sys del %dest%\metakern.sys
if exist %dest%\freedos\bootsect.bin del %dest%\freedos\bootsect.bin
set kernel=kernel.sys

rem Assuming non-freedos bootsector currently installed on diskette
if not exist %dest%\io.sys goto end
%dest%\freedos\copybs.com %dest% %dest%\freedos\bootsect.bin
if not exist %dest%\freedos\bootsect.bin goto end
if not exist %dest%\freedos\meta-all.bin goto end
if not exist %dest%\freedos\metaboot.bot goto end
copy /b %dest%\freedos\meta-all.bin + %dest%\freedos\metaboot.bot + %dest%\freedos\bootsect.bin %dest%\metakern.sys
if exist %dest%\metakern.sys set kernel=metakern.sys
echo SHELL=A:\COMMAND.COM A:\ /E:1024 /D /K set path=a:\freedos> %dest%\config.sys
goto end

:end
echo Kernel file: %kernel%
%dest%\freedos\SYS %dest% %dest% BOOTONLY /K %kernel%
set kernel=
goto end2
:end2